Anachronaut
87d819847e
SWI osExit takes a status in A, and the shell keeps it. Fifty eight exits across twenty three programs now say deliberately whether they worked: 25 did what they were asked, 24 did not, 9 were asked wrongly. Compare is the exception and says so - one there means the files differ, which is a result rather than a failure, the way diff has always had it. IN A RATHER THAN Q, which is not a departure from the rule that a service answers in Q. This one takes an ARGUMENT, the way osPrintNumber takes A and B, and it never returns to answer anything. A is free precisely because a return would have put it back - and Q is the ALU's output, so a small number costs four instructions there against one in A. The shell does not print it. A program that failed has already said so in words and a number beside that is noise, so osLastStatus hands it back and Status is the program that shows it. That indirection is the point: the number exists for the thing that cannot read words. MARKING THE EXITS FOUND A DEFECT ON THE FIRST RUN. Type and More printed why they had failed and then fell through into the success exit, reporting that all was well. Nobody had noticed, because while the only reader was a person, the person could see both the complaint and the claim. Two smaller things. Snake sets the console to line mode and then exits with zero, and the linter flagged the second RSTA as redundant - an exit status and a console mode, equal by accident, which is the class that must never be collapsed. And the README still taught answering by writing into the frame, three months of habit that SRET replaced yesterday; that section is gone and the one describing SRET stands in its place.
76 lines
3.3 KiB
NASM
76 lines
3.3 KiB
NASM
; This is an implementation of The Sieve of Eratosthenes that finds all the primes between 2 and 255.
|
|
|
|
#Include services.asm
|
|
|
|
#Program
|
|
|
|
#Base 0x4000
|
|
|
|
start:
|
|
; Search the list until we find a prime.
|
|
SETD DataTop
|
|
CCF ; Clear the carry flag. In later cycles, the carry flag will be set at the end of the next loop. We'll want it cleared.
|
|
RSTA
|
|
RSTB
|
|
findPrimeLoop:
|
|
LDB ; Load an element into B.
|
|
BRB foundPrime ; If it's zero, it's a prime.
|
|
INCA ; Increment A, our index.
|
|
INCD ; Increment the Data Pointer.
|
|
BRA end ; If A becomes zero, we've looked through the whole list without finding another prime.
|
|
BRI findPrimeLoop ; Keep searching for the next prime.
|
|
foundPrime:
|
|
; If we've found a prime, we should print it and mark it off the list so we don't print it again.
|
|
CALL printByteDecimal ; A contains our prime, so we can just call the print subroutine.
|
|
CALL blankSpace ; Put a space afterward to keep things easy to read.
|
|
INIB 0x01 ; Set B to 1.
|
|
STB ; Mark this prime off the list.
|
|
markMultiples:
|
|
; Now, we mark each multiple of this prime as nonprime until we reach the end of the list.
|
|
PSHD ; Save the Data Pointer to the stack.
|
|
POPB ; Pop its low byte into B.
|
|
ADD ; Add them together.
|
|
PSHQ ; Store the result back onto the stack.
|
|
POPD ; Pop the modified address into the Data Pointer.
|
|
INIB 0x01 ; Set B to 1.
|
|
STB ; Store B to mark the value as nonprime.
|
|
BRC start ; If the previous add overflowed, the next nonprime is outside the range of our list, so start over with a new prime.
|
|
BRI markMultiples ; Otherwise, loop again to mark the next multiple as nonprime.
|
|
end:
|
|
CALL lineFeed ; Print a linefeed to make it look nice.
|
|
RSTA
|
|
SWI osExit ; The program is done, we found all the primes!
|
|
|
|
|
|
|
|
|
|
#Data
|
|
|
|
#Base 0x2000
|
|
|
|
; The table of our prime candidates. It has to begin on a page boundary: marking walks
|
|
; the pointer's low byte and treats the carry out as running off the end of the table,
|
|
; which only finds the right end if the table starts on one.
|
|
|
|
#Align 0x100
|
|
DataTop:
|
|
0x01 0x01 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00
|
|
0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00
|
|
0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00
|
|
0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00
|
|
0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00
|
|
0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00
|
|
0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00
|
|
0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00
|
|
0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00
|
|
0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00
|
|
0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00
|
|
0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00
|
|
0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00
|
|
0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00
|
|
0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00
|
|
0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00 0x00
|
|
|
|
|
|
#Include print.asm
|